Top/Devel/電子工作/Arduino/赤外線学習リモコンR2-D2

/*
 * ir_reciever
 *
 * Date: 2012-08-05 23:55:00 +0900 (Sun, 05  Aug 2012)
 * Author: diabah( http://cubic9.com/ )
 * Original: jun ( http://www.geocities.jp/jun930/ele/irshield.html )
 */

#define DELIMITER "."

// IR packet
int hh,hl;
byte d1h,d1l;
byte d0h,d0l;
byte th,tl;
int len;
byte dat[50];

// last receive time
unsigned long last = 0;

int read_byte(){
  while(Serial.available() == 0);
  return Serial.read();
}

boolean rcv_pkt(){
  int i;
  byte cs = 0;
  
  if(read_byte() != 0xff) return false;
  cs += (i = read_byte());  hh = i * 256;
  cs += (i = read_byte());  hh += i;
  cs += (i = read_byte());  hl = i * 256;  
  cs += (i = read_byte());  hl += i;
  cs += (d1h = read_byte());
  cs += (d1l = read_byte());
  cs += (d0h = read_byte());
  cs += (d0l = read_byte());
  cs += (th = read_byte());
  cs += (tl = read_byte());
  cs += (i = read_byte());  len = i * 256;
  cs += (i = read_byte());  len += i;
  if (len > 400 || len <= 0) return false;
  for(i = 0;i < bytes(); i++){
    cs += (dat[i] = read_byte());
  }
  if(read_byte() != cs) return false;
  
  return true;
}

int bytes(){
  if(len == 0) return 0;
  return (len - 1) / 8 + 1;
}

byte checksum(){
  byte cs = 0;
  int i;
  
  cs += (byte)(hh >> 8) + (byte)(hh & 0xff);
  cs += (byte)(hl >> 8) + (byte)(hl & 0xff);
  cs += d1h + d1l + d0h + d0l + th + tl;
  cs += (byte)(len >> 8) + (byte)(len & 0xff);
  for(i = 0;i < bytes(); i++) cs += dat[i];

  return cs;
}

void snd_pkt(){
  Serial.write((byte)0xff);
  Serial.write((byte)(hh >> 8));
  Serial.write((byte)(hh & 0xff));
  Serial.write((byte)(hl >> 8));
  Serial.write((byte)(hl & 0xff));
  Serial.write(d1h);
  Serial.write(d1l);
  Serial.write(d0h);
  Serial.write(d0l);
  Serial.write(th);
  Serial.write(tl);
  Serial.write((byte)(len >> 8));
  Serial.write((byte)(len & 0xff));
  Serial.write(dat,bytes());
  Serial.write(checksum());
  read_byte();  // receive ACK
}

void setup(){
  pinMode(13,OUTPUT);
  Serial.begin(19200);
  len = 0;
}

void print_pkt(){
  Serial.println();
  Serial.print(int((byte)0xff));
  Serial.print(DELIMITER);
  Serial.print(int((byte)(hh >> 8)));
  Serial.print(DELIMITER);
  Serial.print(int((byte)(hh & 0xff)));
  Serial.print(DELIMITER);
  Serial.print(int((byte)(hl >> 8)));
  Serial.print(DELIMITER);
  Serial.print(int((byte)(hl & 0xff)));
  Serial.print(DELIMITER);
  Serial.print(int(d1h));
  Serial.print(DELIMITER);
  Serial.print(int(d1l));
  Serial.print(DELIMITER);
  Serial.print(int(d0h));
  Serial.print(DELIMITER);
  Serial.print(int(d0l));
  Serial.print(DELIMITER);
  Serial.print(int(th));
  Serial.print(DELIMITER);
  Serial.print(int(tl));
  Serial.print(DELIMITER);
  Serial.print(int((byte)(len >> 8)));
  Serial.print(DELIMITER);
  Serial.print(int((byte)(len & 0xff)));
  Serial.print(DELIMITER);
  int i;
  for(i = 0;i < bytes(); i++){
    Serial.print(int(dat[i]));
  Serial.print(DELIMITER);
  }
  Serial.print(int(checksum()));
  Serial.println();
}

void loop(){
  if (Serial.available() > 0){
    digitalWrite(13,HIGH);
    if(rcv_pkt()){
      last = millis();
    }
    digitalWrite(13,LOW);
  }
  
  if(millis() - last > 1000 && len > 0){
    digitalWrite(13,HIGH);
    snd_pkt();
    digitalWrite(13,LOW);
    Serial.end();

    delay(100);

    digitalWrite(13,HIGH);
    Serial.begin(9600);
    print_pkt();
    digitalWrite(13,LOW);
    Serial.end();

    delay(100);

    Serial.begin(19200);

    len = 0;
  }
}

/*
 * ir_sender
 *
 * Date: 2012-08-05 23:55:00 +0900 (Sun, 05  Aug 2012)
 * Author: diabah( http://cubic9.com/ )
 * Original: Arduino Ofiicial ( http://arduino.cc/en/Tutorial/WebServer )
 */

#include <SPI.h>
#include <Ethernet.h>

#define BEGINNING_OF_LINE 0
#define PREFIX_LENGTH 4
#define DELIMITER "."

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {  0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };
IPAddress ip(192, 168, 0, 40);

// Initialize the Ethernet server library
// with the IP address and port you want to use 
// (port 80 is default for HTTP):
EthernetServer server(3000);

void setup() {
 // Open serial communications and wait for port to open:
  Serial.begin(19200);


  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
}


void loop() {
  char ir_code[255];
  int cusror = 0;
  int ir_cnt = 0;
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    // an http request ends with a blank line
    boolean beginflag = false;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        //Serial.write(c);
        if (cusror == BEGINNING_OF_LINE && c == 'G') {
          // if beginning of line is start with "GET"
          beginflag = true;
        } else 
        if (cusror == PREFIX_LENGTH + 1 && c == 'f') {
          // if GET request is getting favicon
          beginflag = false;
        } else
        if (cusror == BEGINNING_OF_LINE && c == '\r') {
          // if beggining of line is CR
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connnection: close");
          client.println();
          client.println("<html>");
          client.println("<body>");
          client.println(ir_code);
          client.println("</body>");
          client.println("</html>");

          char *part;
          for(part = strtok(ir_code, DELIMITER); part; part = strtok(NULL, DELIMITER)) {
            Serial.write(byte(atoi(part)));
          }
          break;
        } else
        if (beginflag == true) {
          if (cusror == PREFIX_LENGTH) {
            ir_cnt = -1;
          } else if (cusror > PREFIX_LENGTH){
            if (c == ' ') {
              // if current character is the space before "HTTP/1.1"
              ir_code[ir_cnt] = '\0';
              beginflag = false;
            } else {
              ir_code[ir_cnt] = c;
            }
          }
          ir_cnt++;
        }
        cusror++;
        if (c == '\n') {
          cusror = BEGINNING_OF_LINE;
        }
      }
    }
    
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
  }
}

--- ir_sender.ino    Sun Sep 22 00:50:32 2013
+++ ir_sender_apr9600.ino    Sun Sep 22 00:52:44 2013
@@ -13,6 +13,8 @@
 #define PREFIX_LENGTH 4
 #define DELIMITER "."
 
+#define APR9600 2
+
 // Enter a MAC address and IP address for your controller below.
 // The IP address will be dependent on your local network:
 byte mac[] = {  0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };
@@ -24,7 +26,12 @@
 EthernetServer server(3000);
 
 void setup() {
- // Open serial communications and wait for port to open:
+  // initialize the digital pin as an output.
+  pinMode(APR9600, OUTPUT);     
+  // reset digital pin connected to APR9600: 
+  digitalWrite(APR9600, HIGH);
+
+  // Open serial communications and wait for port to open:
   Serial.begin(19200);
 
 
@@ -55,6 +62,23 @@
           // if GET request is getting favicon
           beginflag = false;
         } else
+        if (cusror == PREFIX_LENGTH + 1 && c == 's') {
+          // if GET request is requsting sound
+          beginflag = false;
+          digitalWrite(APR9600, LOW);
+          delay(500);
+          digitalWrite(APR9600, HIGH);
+          client.println("HTTP/1.1 200 OK");
+          client.println("Content-Type: text/html");
+          client.println("Connnection: close");
+          client.println();
+          client.println("<html>");
+          client.println("<body>");
+          client.println("sound");
+          client.println("</body>");
+          client.println("</html>");
+          break;
+        } else
         if (cusror == BEGINNING_OF_LINE && c == '\r') {
           // if beggining of line is CR
           client.println("HTTP/1.1 200 OK");